• NAME
• NOTES
  • Byzantine Internals
  • Stuff that's b0rked
  • Here be monsters
• SEE ALSO
• AUTHOR
• COPYRIGHT AND LICENCE

NAME

HTML::Microformats::Documentation::Notes - misc usage and design notes

NOTES

Byzantine Internals

The internals of HTML::Microformats are pretty complicated - best to steer clear of them. Here are three usage patterns that mostly avoid dealing with the internals:

• Parse a page and use it as a single RDF graph.

  A page can be parsed into an RDF::Trine::Model and queried using SPARQL.

          use HTML::Microformats;
          use LWP::Simple qw[get];
          use RDF::Query;
          
          my $page  = 'http://example.net/';
          my $graph = HTML::Microformats
                         ->new_document(get($page), $page)
                         ->assume_all_profiles
                         ->parse_microformats
                         ->model;
          
          my $query = RDF::Query->new(<<SPARQL);
          PREFIX foaf: <http://xmlns.com/foaf/0.1/>
          SELECT DISTINCT ?friendname ?friendpage
          WHERE {
                  <$page> ?p ?friendpage .
                  ?person foaf:name ?friendname ;
                          foaf:page ?friendpage .
                  FILTER (
                          isURI(?friendpage)
                          && isLiteral(?friendname) 
                          && regex(str(?p), "^http://vocab.sindice.com/xfn#(.+)-hyperlink")
                  )
          }
          SPARQL
          
          my $results = $query->execute($graph);
          while (my $result = $results->next)
          {
                  printf("%s <%s>\n",
                          $result->{friendname}->literal_value,
                          $result->{friendpage}->uri,
                          );
          }

• Use the data method on each object.

  The data method on microformat objects returns a hashref of useful data.

          use HTML::Microformats;
          use LWP::Simple qw[get];
          
          my $page     = 'http://example.net/';
          my @xfn_objs = HTML::Microformats
                         ->new_document(get($page), $page)
                         ->assume_all_profiles
                         ->parse_microformats
                         ->objects('XFN');
          
          while (my $xfn = shift @xfn_objs)
          {
                  printf("%s <%s>\n",
                          $xfn->data->{title},
                          $xfn->data->{href},
                          );
          }

  (If you're wondering why the second example's simpler it's because it returns somewhat dumber data.)

• Convert to other formats.

  Various microformat objects have to_foo methods allowing the data to be exported in various formats..

          use HTML::Microformats;
          use LWP::Simple qw[get];
          
          my $page     = 'http://example.net/';
          my @hcards   = HTML::Microformats
                         ->new_document(get($page), $page)
                         ->assume_all_profiles
                         ->parse_microformats
                         ->objects('hCard');
          
          print $_->to_vcard foreach @hcards;

  Methods available are:

  • to_vcard (hCard objects)

    Exports as vCard 3.0.

  • to_vcard4 (hCard objects)

    Exports as vCard 4.0.

  • to_vcard4_xml (hCard objects)

    Exports as vCard XML.

  • to_icalendar (hCalendar, hEvent, hTodo, hFreebusy, hAlarm and hEntry objects)

    Exports as iCalendar.

  • to_atom (hAtom and hEntry objects)

    Exports as Atom 1.0.

  • to_kml (geo objects)

    Exports as KML 2.0.

  • serialialise_model(as => $format) (all microformat objects)

    Exports as RDF, serialised as $format. (Format can be 'RDFXML', 'Turtle', 'NTriples', 'RDFJSON'.)

Stuff that's b0rked

The get_foo, set_foo, add_foo, clear_foo methods defined in HTML::Microformats::Format work unreliably and are poorly documented. You're better off using the data method and inspecting the returned structure for the data you need. This will be fixed in the future.

Here be monsters

There are several parts of the code which are incredibly complicated and desperately need refactoring. This will be done at some point, so don't rely too much on their current behaviour.

stringify and _stringify_helper in HTML::Microformats::Utilities. The whole of HTML::Microformats::Mixin::Parser.

SEE ALSO

HTML::Microformats.

AUTHOR

Toby Inkster <tobyink@cpan.org>.

COPYRIGHT AND LICENCE

Copyright 2008-2012 Toby Inkster

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.