The Perl Advent Calendar needs more articles for 2022. Submit your idea today!
package Games::ABC_Path::Solver::Move;
$Games::ABC_Path::Solver::Move::VERSION = '0.6.2';
use warnings;
use strict;


use parent 'Games::ABC_Path::Solver::Base';


sub get_text
{
    my $self = shift;

    my $text = $self->_format;

    $text =~ s/%\((\w+)\)\{(\w+)\}/
        $self->_expand_format($1,$2)
        /ge;

    return $text;
}

sub _depth
{
    my $self = shift;

    if (@_)
    {
        $self->{_depth} = shift;
    }

    return $self->{_depth};
}


sub get_depth
{
    my ($self) = @_;

    return $self->_depth();
}

sub _init
{
    my ( $self, $args ) = @_;

    $self->{_text} = $args->{text};
    $self->_depth( $args->{depth} || 0 );
    $self->{_vars} = ( $args->{vars} || {} );

    return;
}


sub bump
{
    my ($self) = @_;

    return ref($self)->new(
        {
            text  => $self->get_text(),
            depth => ( $self->get_depth + 1 ),
            vars  => { %{ $self->{_vars} }, },
        }
    );
}


sub get_var
{
    my ( $self, $name ) = @_;

    return $self->{_vars}->{$name};
}

# TODO : duplicate code with ::Board
my @letters = (qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y));

sub _expand_format
{
    my ( $self, $name, $type ) = @_;

    my $value = $self->get_var($name);

    if ( $type eq "letter" )
    {
        return $letters[$value];
    }
    elsif ( $type eq "coords" )
    {
        return sprintf( "(%d,%d)", $value->x() + 1, $value->y() + 1 );
    }
    else
    {
        die "Unknown format type '$type'!";
    }
}


1;    # End of Games::ABC_Path::Solver::Move

__END__

=pod

=encoding UTF-8

=head1 NAME

Games::ABC_Path::Solver::Move - an ABC Path move.

=head1 VERSION

version 0.6.2

=head1 SYNOPSIS

    use Games::ABC_Path::Solver::Move;

    my $foo = Games::ABC_Path::Solver::Move->new();

=head1 FUNCTIONS

=head2 new

The constructor.

=head2 get_text()

A method that retrieves the text of the move.

=head2 get_depth()

A method that retrieves the solving recursion depth of the move.

=head2 bump

Creates a new identical move with an incremented depth.

=head2 $self->get_var($name)

This method returns the raw, unformatted value of the move's variable (or its
parameter) called $name. Each move class contains several parameters that can
be accessed programatically.

=head1 AUTHOR

Shlomi Fish, C<< <shlomif at cpan.org> >>

=for :stopwords cpan testmatrix url bugtracker rt cpants kwalitee diff irc mailto metadata placeholders metacpan

=head1 SUPPORT

=head2 Websites

The following websites have more information about this module, and may be of help to you. As always,
in addition to those websites please use your favorite search engine to discover more resources.

=over 4

=item *

MetaCPAN

A modern, open-source CPAN search engine, useful to view POD in HTML format.

L<https://metacpan.org/release/Games-ABC_Path-Solver>

=item *

RT: CPAN's Bug Tracker

The RT ( Request Tracker ) website is the default bug/issue tracking system for CPAN.

L<https://rt.cpan.org/Public/Dist/Display.html?Name=Games-ABC_Path-Solver>

=item *

CPANTS

The CPANTS is a website that analyzes the Kwalitee ( code metrics ) of a distribution.

L<http://cpants.cpanauthors.org/dist/Games-ABC_Path-Solver>

=item *

CPAN Testers

The CPAN Testers is a network of smoke testers who run automated tests on uploaded CPAN distributions.

L<http://www.cpantesters.org/distro/G/Games-ABC_Path-Solver>

=item *

CPAN Testers Matrix

The CPAN Testers Matrix is a website that provides a visual overview of the test results for a distribution on various Perls/platforms.

L<http://matrix.cpantesters.org/?dist=Games-ABC_Path-Solver>

=item *

CPAN Testers Dependencies

The CPAN Testers Dependencies is a website that shows a chart of the test results of all dependencies for a distribution.

L<http://deps.cpantesters.org/?module=Games::ABC_Path::Solver>

=back

=head2 Bugs / Feature Requests

Please report any bugs or feature requests by email to C<bug-games-abc_path-solver at rt.cpan.org>, or through
the web interface at L<https://rt.cpan.org/Public/Bug/Report.html?Queue=Games-ABC_Path-Solver>. You will be automatically notified of any
progress on the request by the system.

=head2 Source Code

The code is open to the world, and available for you to hack on. Please feel free to browse it and play
with it, or whatever. If you want to contribute patches, please send me a diff or prod me to pull
from your repository :)

L<https://github.com/shlomif/abc-path>

  git clone https://github.com/shlomif/abc-path

=head1 AUTHOR

Shlomi Fish <shlomif@cpan.org>

=head1 BUGS

Please report any bugs or feature requests on the bugtracker website
L<https://github.com/shlomif/abc-path/issues>

When submitting a bug or request, please include a test-file or a
patch to an existing test-file that illustrates the bug or desired
feature.

=head1 COPYRIGHT AND LICENSE

This software is Copyright (c) 2020 by Shlomi Fish.

This is free software, licensed under:

  The MIT (X11) License

=cut