use strict;
use warnings;

use Test::More tests => 7;

=pod


This example is take from: http://www.python.org/2.3/mro.html

"My second example"
class O: pass
class F(O): pass
class E(O): pass
class D(O): pass
class C(D,F): pass
class B(E,D): pass
class A(B,C): pass

                           6
                          ---
Level 3                  | O |
                       /  ---  \
                      /    |    \
                     /     |     \
                    /      |      \
                  ---     ---    ---
Level 2        2 | E | 4 | D |  | F | 5
                  ---     ---    ---
                   \      / \     /
                    \    /   \   /
                     \  /     \ /
                      ---     ---
Level 1            1 | B |   | C | 3
                      ---     ---
                       \       /
                        \     /
                          ---
Level 0                0 | A |
                          ---

>>> A.mro()
(<class '__main__.A'>, <class '__main__.B'>, <class '__main__.E'>,
<class '__main__.C'>, <class '__main__.D'>, <class '__main__.F'>,
<type 'object'>)

=cut

{
    package Test::O;
    use Class::C3;

    sub O_or_D { 'Test::O' }
    sub O_or_F { 'Test::O' }

    package Test::F;
    BEGIN { our @ISA = ('Test::O'); }
    use Class::C3;

    sub O_or_F { 'Test::F' }

    package Test::E;
    BEGIN { our @ISA = ('Test::O'); }
    use Class::C3;

    package Test::D;
    BEGIN { our @ISA = ('Test::O'); }
    use Class::C3;

    sub O_or_D { 'Test::D' }
    sub C_or_D { 'Test::D' }

    package Test::C;
    BEGIN { our @ISA = ('Test::D', 'Test::F'); }
    use Class::C3;

    sub C_or_D { 'Test::C' }

    package Test::B;
    BEGIN { our @ISA = ('Test::E', 'Test::D'); }
    use Class::C3;

    package Test::A;
    BEGIN { our @ISA = ('Test::B', 'Test::C'); }
    use Class::C3;
}

Class::C3::initialize();

is_deeply(
    [ Class::C3::calculateMRO('Test::A') ],
    [ qw(Test::A Test::B Test::E Test::C Test::D Test::F Test::O) ],
    '... got the right MRO for Test::A');

is(Test::A->O_or_D, 'Test::D', '... got the right method dispatch');
is(Test::A->O_or_F, 'Test::F', '... got the right method dispatch');

# NOTE:
# this test is particularly interesting because the p5 dispatch
# would actually call Test::D before Test::C and Test::D is a
# subclass of Test::C
is(Test::A->C_or_D, 'Test::C', '... got the right method dispatch');

Class::C3::uninitialize();

is(Test::A->O_or_D, 'Test::O', '... old dispatch order is restored');
is(Test::A->O_or_F, 'Test::O', '... old dispatch order is restored');
is(Test::A->C_or_D, 'Test::D', '... old dispatch order is restored');