NAME

perldla - Simple shell for PDLA (see also pdla2)

SYNOPSIS

Use PDLA interactively:

  bash$ perldla
  pdla> $x = sequence(10) # or any other perl or PDLA command
  
  bash$ pdla
  pdla> print "Hello, world!\n"; 

Run a script:

  bash$ cat > pdlscript
  #!/usr/bin/pdla
  print "Hello, world!\n";
  ...

DESCRIPTION

The program perldla is a simple shell (written in perl) for interactive use of PDLA. It consists of a command-line interface that supports immediate interpretation of perl commands and expressions. Perl expressions, including PDLA constructs, can be entered directly at the keyboard and are compiled and executed immediately. The syntax is not exactly identical to Perl, in that under most circumstances ending a line causes immediate execution of the command entered so far (no trailing ';' is required).

The synonym pdla is a compiled executable that is useful as a script interpreter using UNIX shebang (#!) syntax. This is useful for generating and re-executing command-journal files from perldla.

The perldla shell runs an initial startup file (~/.perldlrc) that can be used to pre-load perl modules or configure the global perl environment. It features a path mechanism for autoloading perl subroutines. There is a command-history mechanism, and several other useful features such as command preprocessing, shortcuts for commonly used commands such as "print", and the ability to execute arbitrary code whenever a prompt is printed.

Depending on your configuration settings, perldla can be set to honor or ignore the ^D (end-of-file) character when sent from a terminal, or to attempt to do the Right Thing when a block construct spanning multiple lines is encountered.

perldla and pdla support several command-line options, which are discussed near the end of this document.

Reference manual & online help

The PDLA reference manual and online help are available from within perldla, using the help and apropos commands (which may also be abbreviated ? and ??.) The help command alone prints a summary of help syntax, and help <module-name> will print POD documentation from the module you mention (POD is the Perl format for embedding documentation in your perl code; see perlpod for details).

If you include POD documentation in your autoload subroutines (see path mechanism below), then both help and apropos will find it and be able to format and display it on demand.

History mechanism

If you have the perl modules ReadLines and ReadKeys installed, then perldla supports a history and line-editing mechanism using editing keys similar to emacs. The last 500 commands are always stored in the file .perldl_hist in your home directory between sessions. Set $PERLDL::HISTFILESIZE to change the number of lines saved. The command l [number] shows you the last number commands you typed where number defaults to 20.

e.g.:

   bash$ perldla
   ReadLines enabled
   pdla> $x = rfits "foo.fits"
   BITPIX =  -32  size = 88504 pixels
   Reading  354016 bytes
   BSCALE =  &&  BZERO =

   pdla> imag log($x+400)
   Displaying 299 x 296 image from 4.6939525604248 to 9.67116928100586 ...

Command execution

If you enter a simple command at the perldla command line, it is immediately executed in a Perl eval(). The environment is almost identical to that within a perl script, with some important exceptions:

  • $_ is not preserved across lines

    $_ is used to hold the command line for initial processing, so at the beginning of processing of each command line, $_ contains the command itself. Use variables other than $_ to store values across lines.

  • Scope is not preserved across lines

    Each command line is executed in a separate eval block within perl, so scoping commands such as my and local may not perform exactly as expected -- in particular, if you declare a variable with my, it is local to the particular command line on which you typed the my command, which means that it will evaporate before the next prompt is printed. (You can use my variables in a multi-line block or to isolate values within a single command line, of course).

      NOTE: pdla2 preserves lexical scope between lines.
  • Execution is immediate

    Under most circumstances, as soon as you end a line of input the line is parsed and executed. This breaks Perl's normal dependence on semicolons as command delimiters. For example, the two-line expression

      print "Hello ",
         "world";

    prints the phrase Hello world in Perl, but (under most circumstances) Hello in perldla.

  • Multi-line execution

    In multiline mode (which is enabled by default, see Shell variables, below), perldla searches for searches for block-like constructs with curly braces, parentheses, quotes, and related delimiters. If you leave such a construct open, perldla accepts more lines of input until you close the construct or explicitly end the multi-line expression with ^D. Following the example above, the phrase

      { print "Hello ",
           "world"; }

    will print "Hello world" from either Perl or (in multi-line mode) perldla.

    Warning: The multi-line parsing uses Damian Conway's Text::Balanced module, which contains some flaws -- so it can be fooled by quote-like operators such as q/.../, included POD documentation, multi-line << quotes, and some particularly bizarre-but-valid m/.../ matches and s/.../.../ substitutions. In such cases, use ^D to close out the multi-line construct and force compilation-and-execution.

If you want to preserve this behavior in a script (for example to replay a command journal file; see below on how to create one), you can use pdla instead of perl as the interpreter in the script's initial shebang line.

Terminating perldla

A perldla session can be terminated with any of the commands quit, exit or the shorthands x or q. If EOF handling is switched on (the default) you can also type ^D at the command prompt.

If the command input is NOT a terminal (for example if you are running from a command journal file), then EOF will always terminate perldla.

Terminating commands (Ctrl-C handling)

Commands executed within perldla can be terminated prematurely using Ctrl-C (or whichever key sequence sends an INT signal to the process on your terminal). Provided your PDLA code does not ignore sigints this should throw you back at the perldla command prompt:

  pdla> $result = start_lengthy_computation()
   <Ctrl-C>
 Ctrl-C detected

  pdla>

Shortcuts and aliases

  • The shell aliases p to be a convenient short form of print, e.g.

       pdla> p ones 5,3
    
       [
        [1 1 1 1 1]
        [1 1 1 1 1]
        [1 1 1 1 1]
       ]
  • q and x are short-hand for quit.

  • l lists the history buffer

      pdla> l # list last 20 commands
    
      pdla> l 40 # list last 40 commands
  • ? is an alias for help

      pdla> ? pdla2    # get help for new pdla2 shell
  • ?? is an alias for apropos

      pdla> ?? PDLA::Doc
  • help, apropos, usage and sig: all words after these commands are used verbatim and not evaluated by perl. So you can write, e.g.,

      pdla> help help

    instead of

      pdla> help 'help'

Command-line options

perldla and pdla support several command-line options to adjust the behavior of the session. Most of them are equivalent to commands that can be entered at the pdla> prompt. They are:

-glut

Load OpenGL when starting the shell (the perl OpenGL module, which is available from CPAN must be installed). This enables readline event loop processing. Don't use with -tk.

-tk

Load Tk when starting the shell (the perl Tk module, which is available from CPAN must be installed). This enables readline event loop processing. Don't use with -glut.

-f file

Loads the file before processing any user input. Any errors during the execution of the file are fatal.

-w

Runs with warning messages (i.e. the normal perl -w warnings) turned-on.

-M module

Loads the module before processing any user input. Compare corresponding perl switch.

-m module

Unloads the module before processing any user input.

-I directory

Adds directory to the include path. (i.e. the @INC array) Compare corresponding perl switch.

-V

Prints a summary of PDLA config. This information should be included with any PDLA bug report. Compare corresponding perl switch.

The startup file ~/.perldlrc

If the file ~/.perldlrc is found it is sourced at start-up to load default modules, set shell variables, etc. If it is NOT found the distribution file PDLA/default.perldlrc is read instead. This loads various modules considered useful by default, and which ensure compatibility with v1.11. If you don't like this and want a more streamlined set of your own favourite modules simple create your own ~/.perldlrc. You may wish to start from the existing PDLA/default.perldlrc as a template since it will not be sourced once you replace it with your own version.

To set even more local defaults the file local.perldlrc (in the current directory) is sourced if found. This lets you load modules and define subroutines for the project in the current directory.

The name is chosen specifically because it was found hidden files were NOT wanted in these circumstances.

The startup file should normally include "use PDLA::AutoLoader;", as many of the nicer interactive features won't work without it.

Shell variables

Shell variables: (Note: if you don't like the defaults change them in ~/.perldlrc)

  • $PERLDL::ESCAPE - default value '#'

    Any line starting with this character is treated as a shell escape. The default value is chosen because it escapes the code from the standard perl interpreter.

  • $PERLDL::HISTFILESIZE - default value 500

    This is the number of lines of perldla shell command history to keep.

  • $PERLDL::PAGER - default value more

    External program to filter the output of commands. Using more prints output one screenful at a time. On Unix, setting page(1) and $PERLDL::PAGER to tee -a outfile will keep a record of the output generated by subsequent perldla commands (without paging).

  • $PERLDL::PROMPT - default value 'pdla> '

    Enough said But can also be set to a subroutine reference, e.g. $PERLDL::PROMPT = sub {join(':',(gmtime)[2,1,0]).'> '} puts the current time into the prompt.

  • $PERLDL::MULTI - default value 1

    If this is set to a true value, then perldla will parse multi-line perl blocks: your input will not be executed until you finish a line with no outstanding group operators (such as quotes, blocks, parenthesis, or brackets) still active. Continuation lines have a different prompt that shows you what delimiters are still active.

    Note that this is not (yet!) a complete perl parser. In particular, Text::Balanced appears to be able to ignore quoting operatores like q/ ... / within a line, but not to be able to extend them across lines. Likewise, there is no support for the '<<' operator.

    Multiline conventional strings and {}, [], and () groupings are well supported.

  • $PERLDL::NO_EOF - default value 0 / 1 on MSWin32

    Protects against accidental use of "^D" from the terminal. If this is set to a true value, then you can't accidentally exit perldla by typing "^D". If you set it to a value larger than 1 (and PERLDL::MULTI is set), then you can't use "^D" to exit multiline commands either. If you're piping commands in from a file or pipe, this variable has no effect.

  • $HOME

    The user's home directory

  • $PERLDL::TERM

    This is the Term::ReadLine object associated with the perldla shell. It can be used by routines called from perldla if your command is interactive.

  • $PDLA::toolongtoprint

    The maximal size pdls to print (defaults to 10,000 elements). This is not just a perldla or pdla2 variable but it is something that is usually needed in an interactive debugging session.

Executing scripts from the perldla prompt

A useful idiom for developing perldla scripts or editing functions on-line is

  pdla> # emacs script &
    -- add perldla code to script and save the file
  
  pdla> do 'script'

-- substitute your favourite window-based editor for 'emacs' (you may also need to change the '&' on non-Unix systems).

Running "do 'script'" again updates any variables and function definitions from the current version of 'script'.

Executing perldla scripts from the command line

PDLA scripts are just perl scripts that happen to use PDLA (and possibly PDLA::NiceSlice). But for the truly lazy, perldla can be invokes as a script interpreter. Because perldla is itself an interpreted perl script, most unices won't allow you to say "#!/usr/bin/perldla" at the top of your script.

Instead, say "#!/usr/bin/pdla" and your script will be executed exactly as if you typed it, line-by-line, into the perldla shell.

Command preprocessing

NOTE: This feature is used by default by PDLA::NiceSlice. See below for more about slicing at the perldla prompt

In some cases, it is convenient to process commands before they are sent to perl for execution. For example, this is the case where the shell is being presented to people unfamiliar with perl but who wish to take advantage of commands added locally (eg by automatically quoting arguments to certain commands).

*NOTE*: The preprocessing interface has changed from earlier versions! The old way using $PERLDL::PREPROCESS will still work but is strongly deprecated and might go away in the future.

You can enable preprocessing by registering a filter with the preproc_add function. preproc_add takes one argument which is the filter to be installed. A filter is a Perl code reference (usually set in a local configuration file) that will be called, with the current command string as argument, just prior to the string being executed by the shell. The modified string should be returned. Note that you can make perldla completely unusable if you fail to return the modified string; quitting is then your only option.

Filters can be removed from the preprocessing pipeline by calling preproc_del with the filter to be removed as argument. To find out if a filter is currently installed in the preprocessing pipeline use preproc_registered:

  pdla> preproc_add $myfilter unless preproc_registered $myfilter;

Previous versions of perldla used the variable $PERLDL::PREPROCESS. This will still work but should be avoided. Please change your scripts to use the preproc_add etc functions.

The following code would check for a call to function 'mysub' and bracket arguments with qw.

  $filter = preproc_add sub {
     my $str = shift;
     $str =~ s/^\s+//;  # Strip leading space
     if ($str =~ /^mysub/) {
        my ($command, $arguments) = split(/\s+/,$str, 2);
        $str = "$command qw( $arguments )" 
        if (defined $arguments && $arguments !~ /^qw/);
     };
     # Return the input string, modified as required
     return $str;
   };

This would convert:

  pdla> mysub arg1 arg2

to

  pdla> mysub qw( arg1 arg2 )

which Perl will understand as a list. Obviously, a little more effort is required to check for cases where the caller has supplied a normal list (and so does not require automatic quoting) or variable interpolation is required.

You can remove this preprocessor using the preproc_del function which takes one argument (the filter to be removed, it must be the same coderef that was returned from a previous preproc_add call):

  pdla> preproc_del $filter;

An example of actual usage can be found in the perldla script. Look at the function trans to see how the niceslicing preprocessor is enabled/disabled.

perldla and PDLA::NiceSlice

PDLA::NiceSlice introduces a more convenient slicing syntax for piddles. In current versions of perldla and pdla2 niceslicing is enabled by default (if the required CPAN modules are installed on your machine).

At startup perldla will let you know if niceslicing is enabled. The startup message will contain info to this end, something like this:

   perlDL shell v1.XX
    PDLA comes with ABSOLUTELY NO WARRANTY. For details, see the file
    'COPYING' in the PDLA distribution. This is free software and you
    are welcome to redistribute it under certain conditions, see
    the same file for details.
   ReadLines, NiceSlice  enabled
   Reading /home/csoelle/.perldlrc...
   Type 'demo' for online demos
   Loaded PDLA v2.XX

When you get such a message that indicates NiceSlice is enabled you can use the enhanced slicing syntax:

  pdla> $x = sequence 10;
  pdla> p $x(3:8:2)

For details consult PDLA::NiceSlice.

PDLA::NiceSlice installs a filter in the preprocessing pipeline (see above) to enable the enhanced slicing syntax. You can use a few commands in the perldla shell to switch this preprocessing on or off and also explicitly check the substitutions that the NiceSlice filter makes.

You can switch the PDLA::NiceSlice filter on and off by typing

  pdla> trans # switch niceslicing on

and

  pdla> notrans # switch niceslicing off

respectively. The filter is on by default.

To see how your commands are translated switch reporting on:

  pdla> report 1;
  pdla> p $x(3:8:2)
  processed p $x->nslice([3,8,2])
  [3 5 7]

Similarly, switch reporting off as needed

  pdla> report 0;
  pdla>  p $x(3:8:2)
  [3 5 7]

Reporting is off by default.

Automatically execute your own hooks

The variable @PERLDL::AUTO is a simple list of perl code strings and/or code reference. It is used to define code to be executed automatically every time the user enters a new line.

A simple example would be to print the time of each command:

  pdla> push @PERLDL::AUTO,'print scalar(gmtime),"\n"'
  
  pdla> print zeroes(3,3)
  Sun May  3 04:49:05 1998
  
  [
   [0 0 0]
   [0 0 0]
   [0 0 0]
  ]
  
  pdla> print "Boo"
  Sun May  3 04:49:18 1998
  Boo
  pdla>

Or to make sure any changes in the file 'local.perldlrc' are always picked up :-

  pdla> push @PERLDL::AUTO,"do 'local.perldlrc'"

This code can of course be put *in* 'local.perldlrc', but be careful :-) [Hint: add unless ($started++) to above to ensure it only gets done once!]

Another example application is as a hook for Autoloaders (e.g. PDLA::AutoLoader) to add code too which allows them to automatically re-scan their files for changes. This is extremely convenient at the interactive command line. Since this hook is only in the shell it imposes no inefficiency on PDLA scripts.

Finally note this is a very powerful facility - which means it should be used with caution!