NAME

Test::Stream::HashBase - Base class for classes that use a hashref of a hash.

DEPRECATED

This distribution is deprecated in favor of Test2, Test2::Suite, and Test2::Workflow.

See Test::Stream::Manual::ToTest2 for a conversion guide.

SYNOPSIS

A class:

    package My::Class;
    use strict;
    use warnings;

    use Test::Stream::HashBase accessors => [qw/foo bar baz/];

    # Chance to initialize defaults
    sub init {
        my $self = shift;    # No other args
        $self->{+FOO} ||= "foo";
        $self->{+BAR} ||= "bar";
        $self->{+BAZ} ||= "baz";
    }

    sub print {
        print join ", " => map { $self->{$_} } FOO, BAR, BAZ;
    }

Subclass it

    package My::Subclass;
    use strict;
    use warnings;

    # Note, you should subclass before loading HashBase.
    use base 'My::Class';
    use Test::Stream::HashBase accessors => ['bat'];

    sub init {
        my $self = shift;

        # We get the constants from the base class for free.
        $self->{+FOO} ||= 'SubFoo';
        $self->{+BAT} || = 'bat';

        $self->SUPER::init();
    }

use it:

    package main;
    use strict;
    use warnings;
    use My::Class;

    my $one = My::Class->new(foo => 'MyFoo', bar => 'MyBar');

    # Accessors!
    my $foo = $one->foo;    # 'MyFoo'
    my $bar = $one->bar;    # 'MyBar'
    my $baz = $one->baz;    # Defaulted to: 'baz'

    # Setters!
    $one->set_foo('A Foo');
    $one->set_bar('A Bar');
    $one->set_baz('A Baz');

    # Clear!
    $one->clear_foo;
    $one->clear_bar;
    $one->clear_baz;

    $one->{+FOO} = 'xxx';

DESCRIPTION

This package is used to generate classes based on hashrefs. Using this class will give you a new() method, as well as generating accessors you request. Generated accessors will be getters, set_ACCESSOR setters will also be generated for you. You also get constants for each accessor (all caps) which return the key into the hash for that accessor. Single inheritence is also supported.

IMPORT ARGUMENTS

accessors => [...]

This is how you define your accessors. See the ACCESSORS section below.

base => $class

*** DEPRECATED *** Just use base 'Parent::Class'; before loading HashBase.

This is how you subclass a Test::Stream::Hashbase class. This will give you all the constants of the parent(s).

into => $class

This is a way to apply HashBase to another class.

    package My::Thing;

    sub import {
        my $caller = caller;
        Test::Stream::HashBase->import(@_, into => $class);
        ...
    }

METHODS

PROVIDED BY HASH BASE

$it = $class->new(@VALUES)

Create a new instance using key/value pairs.

HOOKS

$self->init()

This gives you the chance to set some default values to your fields. The only argument is $self with its indexes already set from the constructor.

ACCESSORS

To generate accessors you list them when using the module:

    use Test::Stream::HashBase accessors => [qw/foo/];

This will generate the following subs in your namespace:

foo()

Getter, used to get the value of the foo field.

set_foo()

Setter, used to set the value of the foo field.

clear_foo()

Clearer, used to completely remove the 'foo' key from the object hash.

FOO()

Constant, returs the field foo's key into the class hashref. Subclasses will also get this function as a constant, not simply a method, that means it is copied into the subclass namespace.

The main reason for using these constants is to help avoid spelling mistakes and similar typos. It will not help you if you forget to prefix the '+' though.

SUBCLASSING

You can subclass an existing HashBase class.

    use Test::Stream::HashBase
        base      => 'Another::HashBase::Class',
        accessors => [qw/foo bar baz/];

The base class is added to @ISA for you, and all constants from base classes are added to subclasses automatically.

UTILITIES

hashbase has a handful of class methods that can be used to generate accessors. These methods ARE NOT exported, and are not attached to objects created with hashbase.

$sub = Test::Stream::HashBase->gen_accessor($field)

This generates a coderef that acts as an accessor for the specified field.

$sub = Test::Stream::HashBase->gen_getter($field)

This generates a coderef that acts as a getter for the specified field.

$sub = Test::Stream::HashBase->get_setter($field)

This generates a coderef that acts as a setter for the specified field.

These all work in the same way, except that getters only get, setters always set, and accessors can get and/or set.

    my $sub = Test::Stream::HashBase->gen_accessor('foo');
    my $foo = $obj->$sub();
    $obj->$sub('value');

You can also add the sub to your class as a named method:

    *foo = Test::Stream::HashBase->gen_accessor('foo');

SOURCE

The source code repository for Test::Stream can be found at http://github.com/Test-More/Test-Stream/.

MAINTAINERS

Chad Granum <exodist@cpan.org>

AUTHORS

Chad Granum <exodist@cpan.org>

COPYRIGHT

Copyright 2015 Chad Granum <exodist7@gmail.com>.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

See http://dev.perl.org/licenses/