PDLA::NiceSlice - toward a nicer slicing syntax for PDLA


  use PDLA::NiceSlice;

  $x(1:4) .= 2;             # concise syntax for ranges
  print $y((0),1:$end);     # use variables in the slice expression
  $x->xchg(0,1)->(($pos-1)) .= 0; # default method syntax

  $idx = long 1, 7, 3, 0;   # a piddle of indices
  $x(-3:2:2,$idx) += 3;     # mix explicit indexing and ranges
  $x->clump(1,2)->(0:30);   # 'default method' syntax
  $x(myfunc(0,$var),1:4)++; # when using functions in slice expressions
                            # use parentheses around args!

  $y = $x(*3);              # Add dummy dimension of order 3

  # modifiers are specified in a ;-separated trailing block
  $x($x!=3;?)++;            # short for $x->where($x!=3)++
  $x(0:1114;_) .= 0;        # short for $x->flat->(0:1114)
  $y = $x(0:-1:3;|);        # short for $x(0:-1:3)->sever
  $n = sequence 3,1,4,1;
  $y = $n(;-);              # drop all dimensions of size 1 (AKA squeeze)
  $y = $n(0,0;-|);          # squeeze *and* sever
  $c = $x(0,3,0;-);         # more compact way of saying $x((0),(3),(0))


Slicing is a basic, extremely common operation, and PDLA's slice method would be cumbersome to use in many cases. PDLA::NiceSlice rectifies that by incorporating new slicing syntax directly into the language via a perl source filter (see the perlfilter man page). NiceSlice adds no new functionality, only convenient syntax.

NiceSlice is loaded automatically in the perldla or pdla2 shell, but (to avoid conflicts with other modules) must be loaded explicitly in standalone perl/PDLA scripts (see below). If you prefer not to use a prefilter on your standalone scripts, you can use the slice method in those scripts, rather than the more compact NiceSlice constructs.

Use in scripts and perldla or pdla2 shell

The new slicing syntax can be switched on and off in scripts and perl modules by using or unloading PDLA::NiceSlice.

But now back to scripts and modules. Everything after use PDLA::NiceSlice will be translated and you can use the new slicing syntax. Source filtering will continue until the end of the file is encountered. You can stop sourcefiltering before the end of the file by issuing a no PDLA::NiceSlice statement.

Here is an example:

  use PDLA::NiceSlice;

  # this code will be translated
  # and you can use the new slicing syntax

  no PDLA::NiceSlice;

  # this code won't
  # and the new slicing syntax will raise errors!

See also Filter::Simple and example in this distribution for further examples.

NOTE: Unlike "normal" modules you need to include a use PDLA::NiceSlice call in each and every file that contains code that uses the new slicing syntax. Imagine the following situation: a file

   # start
   use PDLA;
   use PDLA::NiceSlice;

   $x = sequence 10;
   print $x(0:4),"\n";

   require '';
   # end

that requires a second file

   # begin
   $aa = sequence 11;
   print $aa(0:7),"\n";
   # end

Following conventional perl wisdom everything should be alright since we used PDLA and PDLA::NiceSlice already from within and by the time is required things should be defined and imported, etc. A quick test run will, however, produce something like the following:

 [0 1 2 3 4]
 syntax error at line 3, near "0:"
 Compilation failed in require at line 7.

This can be fixed by adding the line

  use PDLA::NiceSlice;

before the code in that uses the new slicing syntax (to play safe just include the line near the top of the file), e.g.

   # begin corrected
   use PDLA::NiceSlice;
   $aa = sequence 11;
   print $aa(0:7),"\n";
   # end

Now things proceed more smoothly

 [0 1 2 3 4]
 [0 1 2 3 4 5 6 7]

Note that we don't need to issue use PDLA again. PDLA::NiceSlice is a somewhat funny module in that respect. It is a consequence of the way source filtering works in Perl (see also the IMPLEMENTATION section below).

evals and PDLA::NiceSlice

Due to PDLA::NiceSlice being a source filter it won't work in the usual way within evals. The following will not do what you want:

  $x = sequence 10;
  eval << 'EOE';

  use PDLA::NiceSlice;
  $y = $x(0:5);

  print $y;

Instead say:

  use PDLA::NiceSlice;
  $x = sequence 10;
  eval << 'EOE';

  $y = $x(0:5);

  print $y;

Source filters must be executed at compile time to be effective. And PDLA::NiceFilter is just a source filter (although it is not necessarily obvious for the casual user).

The new slicing syntax

Using PDLA::NiceSlice slicing piddles becomes so much easier since, first of all, you don't need to make explicit method calls. No


calls, etc. Instead, PDLA::NiceSlice introduces two ways in which to slice piddles without too much typing:

  • using parentheses directly following a scalar variable name, for example

       $c = $y(0:-3:4,(0));
  • using the so called default method invocation in which the piddle object is treated as if it were a reference to a subroutine (see also perlref). Take this example that slices a piddle that is part of a perl list @b:

      $c = $b[0]->(0:-3:4,(0));

The format of the argument list is the same for both types of invocation and will be explained in more detail below.

Parentheses following a scalar variable name

An arglist in parentheses following directly after a scalar variable name that is not preceded by & will be resolved as a slicing command, e.g.

  $x(1:4) .= 2;         # only use this syntax on piddles
  $sum += $x(,(1));

However, if the variable name is immediately preceded by a &, for example


it will not be interpreted as a slicing expression. Rather, to avoid interfering with the current subref syntax, it will be treated as an invocation of the code reference $x with argumentlist (4,5).

The $x(ARGS) syntax collides in a minor way with the perl syntax. In particular, ``foreach $var(LIST)'' appears like a PDLA slicing call. NiceSlice avoids translating the ``for $var(LIST)'' and ``foreach $var(LIST)'' constructs for this reason. Since you can't use just any old lvalue expression in the 'foreach' 'for' constructs -- only a real perl scalar will do -- there's no functionality lost. If later versions of perl accept ``foreach <lvalue-expr> (LIST)'', then you can use the code ref syntax, below, to get what you want.

The default method syntax

The second syntax that will be recognized is what I called the default method syntax. It is the method arrow -> directly followed by an open parenthesis, e.g.

  $x->xchg(0,1)->(($pos)) .= 0;

Note that this conflicts with the use of normal code references, since you can write in plain Perl

  $sub = sub { print join ',', @_ };

NOTE: Once use PDLA::NiceSlice is in effect (you can always switch it off with a line no PDLA::NiceSlice; anywhere in the script) the source filter will incorrectly replace the above call to $sub with an invocation of the slicing method. This is one of the pitfalls of using a source filter that doesn't know anything about the runtime type of a variable (cf. the Implementation section).

This shouldn't be a major problem in practice; a simple workaround is to use the &-way of calling subrefs, e.g.:

  $sub = sub { print join ',', @_ };

When to use which syntax?

Why are there two different ways to invoke slicing? The first syntax $x(args) doesn't work with chained method calls. E.g.


won't work. It can only be used directly following a valid perl variable name. Instead, use the default method syntax in such cases:


Similarly, if you have a list of piddles @pdls:

  $y = $pdls[5]->(0:-1);

The argument list

The argument list is a comma separated list. Each argument specifies how the corresponding dimension in the piddle is sliced. In contrast to usage of the slice method the arguments should not be quoted. Rather freely mix literals (1,3,etc), perl variables and function invocations, e.g.

  $x($pos-1:$end,myfunc(1,3)) .= 5;

There can even be other slicing commands in the arglist:

  $x(0:-1:$pdl($step)) *= 2;

NOTE: If you use function calls in the arglist make sure that you use parentheses around their argument lists. Otherwise the source filter will get confused since it splits the argument list on commas that are not protected by parentheses. Take the following example:

  sub myfunc { return 5*$_[0]+$_[1] }
  $x = sequence 10;
  $sl = $x(0:myfunc 1, 2);
  print $sl;
 PDLA barfed: Error in slice:Too many dims in slice
 Caught at file /usr/local/bin/perldla, line 232, pkg main

The simple fix is

  $sl = $x(0:myfunc(1, 2));
  print $sl;
 [0 1 2 3 4 5 6 7]

Note that using prototypes in the definition of myfunc does not help. At this stage the source filter is simply not intelligent enough to make use of this information. So beware of this subtlety.

Another pitfall to be aware of: currently, you can't use the conditional operator in slice expressions (i.e., ?:, since the parser confuses them with ranges). For example, the following will cause an error:

  $x = sequence 10;
  $y = rand > 0.5 ? 0 : 1; # this one is ok
  print $x($y ? 1 : 2);    # error !
 syntax error at (eval 59) line 3, near "1,

For the moment, just try to stay clear of the conditional operator in slice expressions (or provide us with a patch to the parser to resolve this issue ;).


Following a suggestion originally put forward by Karl Glazebrook the latest versions of PDLA::NiceSlice implement modifiers in slice expressions. Modifiers are convenient shorthands for common variations on PDLA slicing. The general syntax is


Four modifiers are currently implemented:

  • _ : flatten the piddle before applying the slice expression. Here is an example

       $y = sequence 3, 3;
       print $y(0:-2;_); # same as $y->flat->(0:-2)
     [0 1 2 3 4 5 6 7]

    which is quite different from the same slice expression without the modifier

       print $y(0:-2);
      [0 1]
      [3 4]
      [6 7]
  • | : sever the link to the piddle, e.g.

       $x = sequence 10;
       $y = $x(0:2;|)++;  # same as $x(0:2)->sever++
       print $y;
     [1 2 3]
       print $x; # check if $x has been modified
     [0 1 2 3 4 5 6 7 8 9]
  • ? : short hand to indicate that this is really a where expression

    As expressions like


    are used very often you can write that shorter as


    With the ?-modifier the expression preceding the modifier is not really a slice expression (e.g. ranges are not allowed) but rather an expression as required by the where method. For example, the following code will raise an error:

      $x = sequence 10;
      print $x(0:3;?);
     syntax error at (eval 70) line 3, near "0:"

    That's about all there is to know about this one.

  • - : squeeze out any singleton dimensions. In less technical terms: reduce the number of dimensions (potentially) by deleting all dims of size 1. It is equivalent to doing a reshape(-1). That can be very handy if you want to simplify the results of slicing operations:

      $x = ones 3, 4, 5;
      $y = $x(1,0;-); # easier to type than $x((1),(0))
      print $y->info;
     PDLA: Double D [5]

    It also provides a unique opportunity to have smileys in your code! Yes, PDLA gives new meaning to smileys.

Combining modifiers

Several modifiers can be used in the same expression, e.g.

  $c = $x(0;-|); # squeeze and sever

Other combinations are just as useful, e.g. ;_| to flatten and sever. The sequence in which modifiers are specified is not important.

A notable exception is the where modifier (?) which must not be combined with other flags (let me know if you see a good reason to relax this rule).

Repeating any modifier will raise an error:

  $c = $x(-1:1;|-|); # will cause error
 NiceSlice error: modifier | used twice or more

Modifiers are still a new and experimental feature of PDLA::NiceSlice. I am not sure how many of you are actively using them. Please do so and experiment with the syntax. I think modifiers are very useful and make life a lot easier. Feedback is welcome as usual. The modifier syntax will likely be further tuned in the future but we will attempt to ensure backwards compatibility whenever possible.

Argument formats

In slice expressions you can use ranges and secondly, piddles as 1D index lists (although compare the description of the ?-modifier above for an exception).

  • ranges

    You can access ranges using the usual : separated format:

      $x($start:$stop:$step) *= 4;

    Note that you can omit the trailing step which then defaults to 1. Double colons (::) are not allowed to avoid clashes with Perl's namespace syntax. So if you want to use steps different from the default you have to also at least specify the stop position. Examples:

      $x(::2);   # this won't work (in the way you probably intended)
      $x(:-1:2); # this will select every 2nd element in the 1st dim

    Just as with slice negative indices count from the end of the dimension backwards with -1 being the last element. If the start index is larger than the stop index the resulting piddle will have the elements in reverse order between these limits:

      print $x(-2:0:2);
     [8 6 4 2 0]

    A single index just selects the given index in the slice

      print $x(5);

    Note, however, that the corresponding dimension is not removed from the resulting piddle but rather reduced to size 1:

      print $x(5)->info
     PDLA: Double D [1]

    If you want to get completely rid of that dimension enclose the index in parentheses (again similar to the slice syntax):

      print $x((5));

    In this particular example a 0D piddle results. Note that this syntax is only allowed with a single index. All these will be errors:

      print $x((0,4));  # will work but not in the intended way
      print $x((0:4));  # compile time error

    An empty argument selects the whole dimension, in this example all of the first dimension:

      print $x(,(0));

    Alternative ways to select a whole dimension are

      $x = sequence 5, 5; 
      print $x(:,(0));
      print $x(0:-1,(0));
      print $x(:-1,(0));
      print $x(0:,(0));

    Arguments for trailing dimensions can be omitted. In that case these dimensions will be fully kept in the sliced piddle:

      $x = random 3,4,5;
      print $x->info;
     PDLA: Double D [3,4,5]
      print $x((0))->info;
     PDLA: Double D [4,5]
      print $x((0),:,:)->info;  # a more explicit way
     PDLA: Double D [4,5]
      print $x((0),,)->info;    # similar
     PDLA: Double D [4,5]
  • dummy dimensions

    As in slice, you can insert a dummy dimension by preceding a single index argument with '*'. A lone '*' inserts a dummy dimension of order 1; a '*' followed by a number inserts a dummy dimension of that order.

  • piddle index lists

    The second way to select indices from a dimension is via 1D piddles of indices. A simple example:

      $x = random 10;
      $idx = long 3,4,7,0;
      $y = $x($idx);

    This way of selecting indices was previously only possible using dice (PDLA::NiceSlice attempts to unify the slice and dice interfaces). Note that the indexing piddles must be 1D or 0D. Higher dimensional piddles as indices will raise an error:

      $x = sequence 5, 5;
      $idx2 = ones 2,2;
      $sum = $x($idx2)->sum;
     piddle must be <= 1D at /home/XXXX/.perldlrc line 93

    Note that using index piddles is not as efficient as using ranges. If you can represent the indices you want to select using a range use that rather than an equivalent index piddle. In particular, memory requirements are increased with index piddles (and execution time may be longer). That said, if an index piddle is the way to go use it!

As you might have expected ranges and index piddles can be freely mixed in slicing expressions:

  $x = random 5, 5;
  $y = $x(-1:2,pdl(3,0,1));

piddles as indices in ranges

You can use piddles to specify indices in ranges. No need to turn them into proper perl scalars with the new slicing syntax. However, make sure they contain not more than one element! Otherwise a runtime error will be triggered. First a couple of examples that illustrate proper usage:

  $x = sequence 5, 5;
  $rg = pdl(1,-1,3);
  print $x($rg(0):$rg(1):$rg(2),2);
  [11 14]
  print $x($rg+1,:$rg(0));
  [2 0 4]
  [7 5 9]

The next one raises an error

  print $x($rg+1,:$rg(0:1));
 multielement piddle where only one allowed at XXX/ line 1170.

The problem is caused by using the 2-element piddle $rg(0:1) as the stop index in the second argument :$rg(0:1) that is interpreted as a range by PDLA::NiceSlice. You can use multielement piddles as index piddles as described above but not in ranges. And PDLA::NiceSlice treats any expression with unprotected :'s as a range. Unprotected means as usual "not occurring between matched parentheses".


PDLA::NiceSlice exploits the ability of Perl to use source filtering (see also perlfilter). A source filter basically filters (or rewrites) your perl code before it is seen by the compiler. PDLA::NiceSlice searches through your Perl source code and when it finds the new slicing syntax it rewrites the argument list appropriately and splices a call to the slice method using the modified arg list into your perl code. You can see how this works in the perldla or pdla2 shells by switching on reporting (see above how to do that).


Conditional operator

The conditional operator can't be used in slice expressions (see above).

The DATA file handle

Note: To avoid clobbering the DATA filehandle PDLA::NiceSlice switches itself off when encountering the __END__ or __DATA__ tokens. This should not be a problem for you unless you use SelfLoader to load PDLA code including the new slicing from that section. It is even desirable when working with Inline::Pdlapp, see below.

Possible interaction with Inline::Pdlapp

There is currently an undesired interaction between PDLA::NiceSlice and the new Inline::Pdlapp module (currently only in PDLA CVS). Since PP code generally contains expressions of the type $var() (to access piddles, etc) PDLA::NiceSlice recognizes those incorrectly as slice expressions and does its substitutions. This is not a problem if you use the DATA section for your Pdlapp code -- the recommended place for Inline code anyway. In that case PDLA::NiceSlice will have switched itself off before encountering any Pdlapp code (see above):

    # use with Inline modules
  use PDLA;
  use PDLA::NiceSlice;
  use Inline Pdlapp;

  $x = sequence(10);
  print $x(0:5);



  ... inline stuff

Otherwise switch PDLA::NiceSlice explicitly off around the Inline::Pdlapp code:

  use PDLA::NiceSlice;

  $x = sequence 10;

  no PDLA::NiceSlice; # switch off before Pdlapp code
  use Inline Pdlapp => "Pdlapp source code";

The cleaner solution is to always stick with the DATA way of including your Inline code as in the first example. That way you keep your nice Perl code at the top and all the ugly Pdlapp stuff etc at the bottom.

Bug reports

Feedback and bug reports are welcome. Please include an example that demonstrates the problem. Log bug reports in the PDLA issues tracker at or send them to the pdl-devel mailing list (see


Copyright (c) 2001, 2002 Christian Soeller. All Rights Reserved. This module is free software. It may be used, redistributed and/or modified under the same terms as PDLA itself (see